网站地图 | RSS订阅 老铁博客 - 专业上海SEO上海SEO优化,分享网站优化知识,同时提供上海SEO服务。
你的位置:首页 » 获取字符串
前端脚本

JS格式化手机号码和400电话数字格式

JS格式化手机号码和400电话数字格式

可以格式化为任意位数分隔的格式规范,间隔符只能为-英文减号或 英文空格。

<script language="javascript">
//函数功能:格式化手机号码和400电话格式
//参数:要格式化的字符对象ID,存放新值的对象ID,字符串格式规则(如3-4-4、3 3 4)
//制作:凌陈亮(QQ:57404811)
function formatmobile(id,id2,str){
	var num=trim(window.document.getElementById(id).value); //获取号码并去左右空格
	var renum=""; //函数返回对象
	var arr=new Array();
	var i,m=0,n;
	if(str.indexOf('-')>-1){
		arr=str.split("-");
		for(i=0; i<arr.length; i++){
			n=m+Number(arr[i]);
			renum+=num.substring(m,n);
			if(i<arr.length-1) renum+="-";
			m=n;
		}
	}else{
		arr=str.split(" ");
		for(i=0; i<arr.length; i++){
			n=m+Number(arr[i]);
			renum+=num.substring(m,n);
			if(i<arr.length-1) renum+=" ";
			m=n;
		}
	}
	window.document.getElementById(id2).innerHTML=renum;
}
function trim(str){ //删除左右两端的空格
	return str.replace(/(^\s*)|(\s*$)/g, ""); //过滤首尾空格为空
}
</script>
手机号:<input type="text" name="mobile" id="mobile" value="13023105435" />
格式化后:<span id="fmm"></span>
<p>
<input type="button" value="3-4-4格式" onClick="javascript:formatmobile('mobile','fmm','3-4-4');" />
<input type="button" value="3 4 4格式" onClick="javascript:formatmobile('mobile','fmm','3 4 4');" />
</p>
400电话:<input type="text" name="400tel" id="400tel" value="4008888888" />
格式化后:<span id="fmm2"></span>
<p>
<input type="button" value="3-3-4格式" onClick="javascript:formatmobile('400tel','fmm2','3-3-4');" />
<input type="button" value="3 3 4格式" onClick="javascript:formatmobile('400tel','fmm2','3 3 4');" />
<input type="button" value="3-4-3格式" onClick="javascript:formatmobile('400tel','fmm2','3-4-3');" />
<input type="button" value="3-5-2格式" onClick="javascript:formatmobile('400tel','fmm2','3-5-2');" />
<input type="button" value="3-2-5格式" onClick="javascript:formatmobile('400tel','fmm2','3-2-5');" />
</p>

发布时间:2016年9月19日 | 评论:0 | 浏览: | 标签:Javascript  格式化  获取字符串  

前端脚本

JS删除头尾两端空格

JS删除头尾两端空格

去除字符串左右两边的空格,在vbscript里面可以使用 trim函数,但在js中却没有这个内置方法,需要自己写代码。下面的实现方法用到了正则表达式。

第一种:写成类的方法

<script language="javascript" type="text/javascript">
String.prototype.trim=function(){ //过滤首尾空格
	return this.replace(/(^\s*)|(\s*$)/g, "");
}
</script>

调用方式:

发布时间:2016年9月19日 | 评论:0 | 浏览: | 标签:Javascript  格式化  获取字符串  

ASP程序

ASP获取某条记录的某个字段值函数

ASP获取某条记录的某个字段值函数

<%
'作者:凌陈亮www.lingchenliang.com(QQ:57404811)
'自定义函数功能:根据查询条件表达式获取某条记录的某个字段值
'只适合单一记录的单一字段值获取,一般文章列表中显示文章分类名称时常用
'此函数只为方便代码写作或多处调用时使用,并无什么特殊之处
'参数:表名,查询字段名称,查询值,返回字段名称
function getsys(tb,wfield,wfield_v,getfield)
if len(tb)>0 and len(wfield)>0 and len(wfield_v)>0 and len(getfield)>0 then
dim f_rs
'conn为打开数据库变量
set f_rs=conn.execute("select [" & getfield & "] from [" & tb & "] where [" & wfield & "]=" & wfield_v & "")
if f_rs.bof=false and f_rs.eof=false then getsys=f_rs(0)
set f_rs=nothing
end if
end function
%>

发布时间:2016年1月25日 | 评论:0 | 浏览: | 标签:获取字段值  获取字符串  

ASP程序

ASP生成数字字母图片验证码,可设置位数

ASP生成数字字母图片验证码,可设置位数

发布时间:2015年12月31日 | 评论:3 | 浏览: | 标签:获取字符串  验证码  随机数  

ASP程序

ASP控制每行字数,超出自动换行

ASP控制每行字数,超出自动换行

<%
'函数:指定字符串1每隔n位插入字符串2,1个中文=2个英文【凌陈亮(QQ:57404811)】
'参数:字符串1(原字符串),n位开始插入,字符串2(要插入的字符串)
'功能可实现:控制每行字数,超出自动换行
function insertstr(str,n,insstr)
 dim f_return,f_i,f_m,f_k,f_a
 f_k=0
 for f_i=1 to len(str)
  f_a=mid(str,f_i,1)
  dim re : set re=New RegExp '建立正则表达式
  re.Pattern="[^\x00-\xff]" '设置模式,即建立正则式规则
  re.Global=False '设置全局可用性
  re.Ignorecase=True '设置是否区分字符大小写
  re.MultiLine=False '设置多行标记可用性
  f_m=len(re.replace(f_a,"$2")) '执行搜索测试
  f_k=f_k+f_m
  if f_k<n then
   f_return=f_return & f_a
  elseif f_k=n then
   f_return=f_return & f_a & insstr
   f_k=0
  else
   f_return=f_return & insstr & f_a
   f_k=f_m
  end if
 next
 insertstr=f_return
end function
%>

发布时间:2015年12月30日 | 评论:0 | 浏览: | 标签:获取字符串  自动换行  插入字符串  

ASP程序

ASP格式化提交的特殊字符

ASP格式化提交的特殊字符

<%
'格式化提交的特殊字符【凌陈亮(QQ:57404811)】
'参数:类型(1为SQL查询字符串时使用,0和其它为输出到原表单元素中时使用),字符串
function replace_yinhao(typ,str)
 dim f_str : f_str=str
 if len(f_str)>0 then
  if typ=1 then 'SQL查询语句时使用
   f_str=replace(f_str,"'","''")
   f_str=replace(f_str,"""","""""")
  else '输出到原表单元素中时使用
   f_str=replace(f_str,"&","&amp;")
   f_str=replace(f_str,"#","&#35;")
   f_str=replace(f_str," ","&nbsp;")
   f_str=replace(f_str,"'","&#39;")
   f_str=replace(f_str,"""","&#34;")
   f_str=replace(f_str,"<","&lt;")
   f_str=replace(f_str,">","&gt;")
  end if
 end if
 replace_yinhao=f_str
end function
%>

发布时间:2015年12月30日 | 评论:0 | 浏览: | 标签:获取字符串  格式化  特殊字符  

ASP程序

ASP实现表格隔行换色函数

ASP实现表格隔行换色函数

<%
'ASP实现表格隔行换色函数【凌陈亮(QQ:57404811)】
'参数:i,当前行号(只能为整数);colors,颜色集合(值可为16进制颜色值,也可为标准颜色英文单词,各颜色值之间用"|"符号隔开)

'可实现2、3、4等无限个颜色交替
function getbgcolor(i,colors)
 dim f_return
 if checknum(1,0,i,"","")=1 then
  i=clng(i)
 else
  i=0
 end if
 if len(colors)>0 then
  dim f_colors_arr '定义接收参数colors的颜色样式的数组
  dim f_colors_arr_ubound '定义接收参数colors的颜色个数的变量
  f_colors_arr=split(colors,"|",-1,1) '将所有颜色样式传给数组
  f_colors_arr_ubound=ubound(f_colors_arr,1) '获取数组的上标
  '循环数组的每一个元素
  dim f_i '定义循环数组元素变量
  dim f_mod '定义行号除以颜色个数的余数的变量
  for f_i=0 to f_colors_arr_ubound
   f_mod=i mod (f_colors_arr_ubound+1)
   if f_mod=0 then
    f_return=f_colors_arr(f_colors_arr_ubound)
   else
    f_return=f_colors_arr(f_mod-1)
   end if
  next
 end if
 getbgcolor=f_return
end function

发布时间:2015年12月30日 | 评论:0 | 浏览: | 标签:获取字符串  隔行换色  

ASP程序

asp取左边字符串函数(1个中文=2个英文)

asp取左边字符串函数(1个中文=2个英文)

<%
'取左边N个字符,1个中文=2个英文【凌陈亮(QQ:57404811)】
'参数:字符串,左边位数,超出部分截断的替换字符串(如:...)
function getleftstr(str,n,str_right)
 if len(str)>0 then
  dim f_str,f_i,f_k,f_a
  f_k=0
  for f_i=1 to len(str)
   f_a=mid(str,f_i,1)
   dim re : set re=New RegExp '建立正则表达式
   re.Pattern="[^\x00-\xff]" '设置模式,即建立正则式规则
   re.Global=False '设置全局可用性
   re.Ignorecase=True '设置是否区分字符大小写
   re.MultiLine=False '设置多行标记可用性
   f_k=f_k+len(re.replace(f_a,"$2")) '执行搜索测试
   if f_k<=n then
    f_str=f_str & f_a
   else
    f_str=f_str & str_right
    exit for
   end if
  next
  getleftstr=f_str
 end if
end function
%>

发布时间:2015年12月29日 | 评论:0 | 浏览: | 标签:获取字符串  取左边字符  

ASP程序

ASP获取并规范日期时间格式

ASP获取并规范日期时间格式

<%
'获取并规范日期时间格式【凌陈亮(QQ:57404811)】
'参数:返回类型(0日期时间,1日期,2时间,3日期时间编号),时间
function getnow_cdate(typ,f_now)
 dim f_return
 if len(f_now)>0 then
  dim f_date,f_time
  f_date=year(f_now) & "-" & right("0" & month(f_now),2) & "-" & right("0" & day(f_now),2)
  f_time=right("0" & hour(f_now),2) & ":" & right("0" & minute(f_now),2) & ":" & right("0" & second(f_now),2)
  if typ=0 then
   f_return=f_date & " " & f_time '格式:2015-01-02 03:04:05
  elseif typ=1 then
   f_return=f_date '格式:2015-01-02
  elseif typ=2 then
   f_return=f_time '格式:03:04:05
  else
   '格式:20150102030405(常用于生成订单号)
   f_return=year(f_now) & right("0" & month(f_now),2) & right("0" & day(f_now),2) & right("0" & hour(f_now),2) & right("0" & minute(f_now),2) & right("0" & second(f_now),2)
  end if
  getnow_cdate=f_return
 end if
end function
%>

发布时间:2015年12月29日 | 评论:0 | 浏览: | 标签:获取字符串  日期时间  格式化  

ASP程序

ASP生成随机数(1-11位数字)

ASP生成随机数(1-11位数字)

<%
'生成随机数(1-11位数字)【凌陈亮(QQ:57404811)】
'参数:位数(1-11之间的数字)
function setrannums(n)
 randomize timer() '初始化随机数生成器
 'Int、Fix函数:返回数字的整数部分
 'Left函数:返回左边的指定个数字符串
 'Rnd函数:返回一个小于1但大于或等于0的值
 setrannums=int(left(999999999999*rnd()+100000000000,n))
end function
%>

发布时间:2015年12月29日 | 评论:0 | 浏览: | 标签:获取字符串  随机数  验证码  ASP教程  

ASP程序

ASP过滤HTML标签、JS代码、CSS样式,只获取纯文本

ASP过滤HTML标签、JS代码、CSS样式,只获取纯文本
<%
'函数:ASP过滤HTML标签、JS代码、CSS样式,只获取纯文本【凌陈亮(QQ:57404811)】
'参数:字符串,左边字符数(空为全文,1个中文字符=2个英文字符),超出部分的连接字符串
function gw_nohtml(content,n,nexttext)
	dim f_content : f_content=content
	if len(f_content)>0 then
		dim re : set re=New RegExp	'建立正则表达式
		re.Global=true		'设置全局可用性
		re.Ignorecase=false	'设置是否区分字符大小写
		re.MultiLine=true	'设置多行标记可用性
		re.Pattern="<[sS][tT][yY][lL][eE][^>]*?>[\s\S]*?<\/[sS][tT][yY][lL][eE]>" '去STYLE样式正则式
		f_content=re.replace(f_content,"") '执行搜索测试
		re.Pattern="<[sS][cC][rR][iI][pP][tT][^>]*?>[\s\S]*?<\/[sS][cC][rR][iI][pP][tT]>" '去SCRIPT脚本正则式
		f_content=re.replace(f_content,"") '执行搜索测试
		re.Pattern="<(.|\n)+?>"	'去HTML标签正则式
		f_content=re.replace(f_content,"") '执行搜索测试
		'自适应UNICODE特殊字符
		const utf8str_const="&amp;|&quot;|&lt;|&gt;|&nbsp;|&copy;|&reg;|&raquo;|&Theta;|&acute;|&AElig;|&aelig;|&Agrave;|&agrave;|&Aring;|&aring;|&Atilde;|&atilde;|&Auml;|&auml;|&brvbar;|&Ccedil;|&ccedil;|&cedil;|&cent;|&circ;|&Aacute;|&curren;|&deg;|&divide;|&Eacute;|&eacute;|&Ecirc;|&ecirc;|&Egrave;|&egrave;|&ETH;|&eth;|&Euml;|&euml;|&euro;|&fnof;|&frac12;|&frac14;|&frac34;|&Iacute;|&iacute;|&Icirc;|&icirc;|&iexcl;|&Igrave;|&igrave;|&iquest;|&Iuml;|&iuml;|&laquo;|&macr;|&micro;|&middot;|&not;|&Ntilde;|&ntilde;|&Oacute;|&oacute;|&Ocirc;|&ocirc;|&OElig;|&oelig;|&Ograve;|&ograve;|&ordf;|&ordm;|&Oslash;|&oslash;|&Otilde;|&otilde;|&Ouml;|&ouml;|&para;|&plusmn;|&pound;|&aacute;|&Acirc;|&Scaron;|&scaron;|&sect;|&shy;|&sup1;|&sup2;|&sup3;|&szlig;|&THORN;|&thorn;|&tilde;|&times;|&Uacute;|&uacute;|&Ucirc;|&ucirc;|&Ugrave;|&ugrave;|&uml;|&Uuml;|&uuml;|&Yacute;|&yacute;|&yen;|&Yuml;|&yuml;|&ensp;|&emsp;|&thinsp;|&zwnj;|&zwj;|&lrm;|&rlm;|&ndash;|&mdash;|&lsquo;|&rsquo;|&sbquo;|&ldquo;|&rdquo;|&bdquo;|&lsaquo;|&rsaquo;|&dagger;|&Dagger;|&permil;|&bull;|&hellip;|&Prime;|&oline;|&frasl;|&weierp;|&image;|&real;|&trade;|&alefsym;|&larr;|&uarr;|&rarr;|&darr;|&harr;|&crarr;|&lArr;|&uArr;|&rArr;|&dArr;|&hArr;|&forall;|&part;|&exist;|&empty;|&nabla;|&isin;|&notin;|&ni;|&prod;|&sum;|&minus;|&lowast;|&radic;|&prop;|&infin;|&ang;|&and;|&or;|&cap;|&cup;|&int;|&there4;|&sim;|&cong;|&asymp;|&ne;|&equiv;|&le;|&ge;|&sub;|&sup;|&nsub;|&sube;|&supe;|&oplus;|&otimes;|&perp;|&sdot;|&lceil;|&rceil;|&lfloor;|&rfloor;|&lang;|&rang;|&loz;|&spades;|&clubs;|&hearts;|&diams;|&Alpha;|&alpha;|&Beta;|&beta;|&Gamma;|&gamma;|&Delta;|&delta;|&Epsilon;|&epsilon;|&Zeta;|&zeta;|&Eta;|&eta;|&acirc;|&theta;|&thetasym;|&Iota;|&iota;|&Kappa;|&kappa;|&Lambda;|&lambda;|&Mu;|&mu;|&Nu;|&nu;|&Xi;|&xi;|&Omicron;|&omicron;|&Pi;|&pi;|&piv;|&Rho;|&rho;|&Sigma;|&sigma;|&sigmaf;|&Tau;|&tau;|&Upsilon;|&upsilon;|&upsih;|&Phi;|&phi;|&Chi;|&chi;|&Psi;|&psi;|&Omega;|&omega;"
		dim utf8str : utf8str=split(utf8str_const,"|")
		
		dim f_return
		if len(n)>0 then
			dim f_k : f_k=0
			dim f_i,f_j,f_a,f_b
			for f_i=1 to len(f_content)
				f_a=mid(f_content,f_i,1)
				
				for f_j=0 to ubound(utf8str)
					f_b=mid(f_content,f_i,len(utf8str(f_j)))
					if f_b=utf8str(f_j) then
						f_a=f_b
						f_i=f_i+len(utf8str(f_j))-1
						exit for
					end if
				next
				
				re.Pattern="[^\x00-\xff]"	'设置模式,即建立正则式规则
				f_k=f_k+len(re.replace(f_a,"$2"))	'执行搜索测试
				if f_k<=n then
					f_return=f_return & f_a
				else
					f_return=f_return & nexttext
					exit for
				end if
			next
		else
			f_return=f_content
		end if
		set re=nothing
		gw_nohtml=f_return
	end if
end function
%>

发布时间:2015年8月10日 | 评论:0 | 浏览: | 标签:获取字符串  过滤HTML代码  过滤JS代码  过滤CSS代码  获取纯文本  

«1»